SmartLockerTools/Analyser/qml/OperationItem.qml

import QtQuick
import QtQuick.Controls
import QtQuick.Layouts
import Analyser

ColumnLayout {
    ConnectionItem {}

    GroupBox {
        title: "命令"
        Layout.columnSpan: 2
        enabled: App.connected
        GridLayout {
            columns: 2
            GroupBox {
                title: "注册用户"
                GridLayout {
                    columns: 2
                    Text {
                        text: qsTr("用户姓名")
                    }
                    TextField {
                        id: enrollName
                        implicitWidth: 100
                    }
                    Text {
                        text: qsTr("超时时间")
                    }
                    TextField {
                        id: enrollTimeout
                        implicitWidth: 100
                        text: "10"
                    }
                    Button {
                        text: !App.module ? "注册" : App.module.currentMessageId
                                            === 0x1d ? "取消" : "注册"
                        onClicked: App.module.currentMessageId
                                   === 0x1d ? App.module.reset() : App.enroll(
                                                  enrollName.text,
                                                  parseInt(enrollTimeout.text))
                    }
                }
            }
            GroupBox {
                title: "识别用户"
                GridLayout {
                    columns: 2
                    Text {
                        text: qsTr("超时时间(s)")
                    }
                    TextField {
                        id: verifyTimeout
                        implicitWidth: 80
                        text: "10"
                    }
                    Text {
                        text: qsTr("持续识别")
                    }
                    Switch {
                        checked: App.persistenceMode
                        onToggled: App.persistenceMode = !App.persistenceMode
                    }
                    Text {
                        text: qsTr("识别间隔(s)")
                    }
                    TextField {
                        id: verifyIntetval
                        implicitWidth: 80
                        text: App.persistenceVerifyInterval
                    }
                    Item {}
                    Button {
                        text: App.isVerifying ? "停止" : "识别"
                        onClicked: {
                            if (App.isVerifying) {
                                App.module.reset()
                            } else {
                                App.persistenceVerifyInterval = parseInt(
                                            verifyIntetval.text)
                                App.verify(parseInt(verifyTimeout.text))
                            }
                        }
                    }
                }
            }
            GroupBox {
                title: "删除用户"
                GridLayout {
                    columns: 2
                    Text {
                        text: qsTr("用户ID")
                    }
                    TextField {
                        id: deleteUserId
                        implicitWidth: 100
                    }
                    Button {
                        text: "删除"
                        onClicked: App.deleteUser(parseInt(deleteUserId.text))
                    }
                    Button {
                        text: "删除所有"
                        onClicked: App.deleteAll()
                    }
                }
            }
            GroupBox {
                title: "图片注册"
                GridLayout {
                    columns: 1
                    Button {
                        text: "录入图片上报"
                        onClicked: App.getEnrolledImage("", 60)
                    }
                    Button {
                        text: "图片下发注册"
                        onClicked: App.uploadImage()
                    }
                }
            }
            Button {
                text: "复位"
                onClicked: App.module.reset()
            }
        }
    }
}